AS2 - FLV player light

By: Zao on 14:26

stop();
//declarando variáveis...
var display:Video;
var videoAtual:String = null;
var tempoAtual:Number = 0;
var isPlay:Boolean = false;
//botoes e mcs do player...
var play_mc:MovieClip;
//som para o controle do volume do player...
var somVideo:Sound = new Sound();
//criando conexao do stream de video...
var netConVideo:NetConnection = new NetConnection();
netConVideo.connect(null);
//criando stream para ser usado na conexao...
var netStmVideo:NetStream = new NetStream(netConVideo);
//um pequeno buffer antes do filme começar...
netStmVideo.setBufferTime(3);
//objeto monitor de eventos do video...
netStmVideo.onStatus = function(info)
{
//este if server para verificar se o filme ja acabou, rebobinando o mesmo...
if (info.code == "NetStream.Play.Stop")
{
netStmVideo.play(videoAtual);
stopVideo();
}
};
//adicionando o stream ao nosso display no palco...
display.attachVideo(netStmVideo);
//função responsável por setar o video a ser carregado e tocado...
function setVideo(src:String)
{
//caso o comando de tocar seja pra um video já sendo tocado, evita o recarregamento...
if (videoAtual != src)
{
netStmVideo.play(src);
//salva numa var, o video atual para posterior verificação...
videoAtual = src;
}
else
{
//neste caso o video atual e o mesmo do comando, assim só recomeça a tocar...
netStmVideo.seek(0);
}
//configurando player para que esteja tocando...
play_mc.gotoAndStop(2);
isPlay = true;
}
//função responsável pelo Play/Pause do filme...
function PlayPause()
{
//verifica se o video esta tocando, caso sim, pausa...
if (isPlay)
{
//salva o tempo atual para posterior continuação ao apertar em play...
//esse menos 10 e para não haver corte e delay no tempo de apertar o botão...
tempoAtual = netStmVideo.time -10;
netStmVideo.pause(true);
isPlay = false;
}
else
{
//caso esteja parado continua a tocar da onde parou...
isPlay = true;
netStmVideo.pause(false);
}
}
//função responsável pelo stop do filme...
function stopVideo()
{
//resetando o tempo atual caso esteja em pause...
tempoAtual = 0;
netStmVideo.seek(0);
netStmVideo.pause(true);
isPlay = false;
//joga o botão de play/pause para o frame do play...
play_mc.gotoAndStop(1);
play_mc._alpha = 100;
}
play_mc.onRelease = function()
{
//verifica a atual situação para dizer se deve aparecer o play ou pause...
if (isPlay && this._currentframe == 2)
{
this.gotoAndStop(1);
}
else
{
this.gotoAndStop(2);
}
//ativando a função PlayPause()...
PlayPause();
};

play_mc.onRollOver = function()
{
this._alpha = 100;
};
play_mc.onRollOut = function()
{
if (this._currentframe != 1)
{
this._alpha = 0;
}

};

//por fim damos load e play em nosso video...
setVideo("Shakira_Eau_Florale.flv");

stopVideo();


fonte: http://forum.imasters.com.br/topic/367780-saber-se-o-video-flv-ja-terminou-as2/